"Ruins Remixed" by Brandon Felger (updated by Todd Neller)

Use scoring.  Maximum score is 30. [scoring is not active by default at present - Todd Neller]

When play begins:
say "[italic type]You are once again lost in a jungle far from home. You are ready to give up and go home, disappointed in yet another failed archaeological expedition. Just as you decide to turn back to camp, you suddenly stumble upon something...[roman type]".

The Forest is a room. "You stand in a clearing in the deep jungle. Obscured by centuries of overgrowth and dim sunlight is a ruined temple of some sort. Whatever details there may have been on the stone blocks have long since been worn away[if we have examined the temple]. There is a single, solitary entryway leading downward[end if]."

A mushroom is here. It is edible. It has point value 1.  "A polka-dotted mushroom pokes out of the moist soil. It is possibly scrumptious." The description is "[if we have not examined the mushroom]Upon further examination, you decide that, while possibly scrumptious, it is also possibly a toadstool. You might want to keep examining it[otherwise]Now that you look at it again, you can see clearly that it is a toadstool; a nasty looking one, at that[end if]."

After taking the mushroom:
   say "You deftly snap the mushroom's stalk, and pluck the hapless fungus from its natural habitat."

After dropping the mushroom:
   say "You discard the abused mushroom to the ground like a used facial tissue."
   
After eating the mushroom:
   say "You pop the scrumptulescent mushroom treat into your mouth. It tastes like fungal-flavored candy. The gastronomical delight turns out to be a toadstool, and you succumb to its choking, asphyxiating aftertaste.";
   end the story saying "You have died".

Understand "toadstool" as the mushroom;

After examining the mushroom for the second time:
   now the printed name of the mushroom is "toadstool".
   
The temple is here. It is scenery. The description is "The stone blocks lie tumbled about, as if they were strewn about. Vines cover the upper half, while soil, leaves and grasses cover the bottom half. A set of steep stairs goes straight down into darkness."

The Dark Passage is a room. It is down from the Forest. "This passage is dark and cramped. This is obviously not the original entrance to the temple's underground chambers. It continues to the north. A dim shaft of light comes from the exit to the forest above."

The Token Temple Underground Chamber is a room.  It is north from the Dark Passage. "You are in the single, token underground chamber of the temple that was called for in this tutorial.  The fourth wall has apparently been broken down here.  In the dank chamber, you see on the wall an old Elf movie poster.  It smells of beef and cheese."

Treasure is a kind of thing. It has a number called worth. The worth of a treasure is usually 0.

A Spanish Doubloon is here. It is treasure with worth 1400 and point value 19. "A Spanish Doubloon lies glinting on the floor." The description is "This coin is marked as an eight escudo piece. That's a neat $1.4K in your wallet. [if we have not examined the Doubloon]Are there perhaps more pieces o' eight waiting for plundering?[end if]".

Understand "doubloon" and "coin" and "gold" and "bit" as the Spanish Doubloon;

Photographing is an action applying to one thing. Understand "photograph [something]" as photographing.

[Before photographing the temple:
   say "*click*[line break]You get a great shot of the temple ruins.";
   increase the score by 5.]
   
Things have a number called point value. The point value of a thing is usually 0. The temple has point value 5.

Check photographing:
   if the point value of the noun is 0, say "*click*[line break]You take a picture of a totally uninteresting [printed name]." instead;
   if the point value of the noun is -1, say "You already got a picture of that." instead.

Carry out photographing:
   say "*click*[line break]You get a great shot of the [printed name].";
   increase the score by the point value of the noun;
   now the point value of the noun is -1.
   
An ancient trophy is here. It is treasure with worth 1000000 and point value 5. "An ancient trophy lies here, discarded." The description is "This ancient trophy is worth one million dollars!"

After taking the ancient trophy:
   say "You take the trophy, a item of such worth that you can now return home, satisfied that you have properly plundered the temple!";
   end the story finally.
   
Every turn when the location is the Forest:
if score is 30
begin;
   say "You emerge from the ruined temple, having finally taken photos of all the wonderful artifacts therein.";
   end the story finally;
end if.